; ATTRIBUTUM KONVERTALO
           ORG 3000H     ; A kezdocim
ADDRESS    EQU 5800H     ; Az ADDRESS cimke utan
                         ; (az 5800H helyett) lehet
                         ; beirni a konvertalni
                         ; kivant blokk kezdocimet
LENGTH     EQU 768       ; A LENGTH cimke utan az
                         ; elobbiekhez hasonloan
                         ; a blokk hosszat. Tehat
                         ; a rutin az ADDRESS
                         ; cimtol kezdve LENGTH
                         ; mennyisegu byte-ot
                         ; konvertal
                         ; Ebben a peldaban egy
                         ; teljes SPEC. SCREEN-t
           LD IX,ADDRESS ; IX-ben a kezdocim
           LD BC,LENGTH  ; BC-ben a hossz
C1         LD HL,NORM    ; Ha nincs BRIGHT, akkor
                         ; a normal szinek
                         ; tablazata
           BIT 6,(IX)
           JR Z,C2
           LD HL,BRIGHT  ; Ha van, akkor a fenyes
                         ; szinek tablazata
C2         LD A,(IX)
           LD (IX),0
           CALL C3       ; konvertalas
           INC IX
           DEC BC        ; Addig folytatja, mig az
                         ; osszes byte el nem fogy
           LD A,B
           OR C
           JR NZ,C1
           RET           ; Visszater
C3         CALL C4       ; A konvertalo rutin
C4         PUSH AF
           AND 7
           PUSH HL
           LD E,A
           LD D,0
           ADD HL,DE
           LD E,(HL)
           POP HL
           LD A,(IX)
           OR E
           RLCA
           RLCA
           RLCA
           RLCA
           LD (IX),A
           POP AF
           RRA
           RRA
           RRA
           RET
NORM       DEFB 0,1,2,3,4,5,6,7       ; A normal szinek
BRIGHT     DEFB 8,12,9,13,10,14,11,15 ; A fenyes
                                      ; szinek