ORG 100H        ; Forditasi cim
.SET            MACRO @VALTOZO,@ERTEK
                LD B,1          ; Iras
                LD C,@VALTOZO
                LD D,@ERTEK
                EXOS 16         ; EXOS valtzozo olvasasa, irasa
                                ; vagy atbillentese
                ENDM            ; Makro vege (END Macro)

                LD SP,3FFFH     ; STACK beallitasa (veremmutato)
                .SET 22,1       ; 1-es videomod
                .SET 23,0       ; 2-szinu uzemmod
                .SET 24,30      ; 30 oszlop szeles
                .SET 25,20      ; 20 sor magas

                ;Csatorna megnyitasa
                LD A,1          ; A-ba a csatornaszam
                LD DE,VID       ; DE a nev elotti hosszbyte-ra mutat
                EXOS 2          ; Csatorna megnyitasa irasra

                ;Videolap megjelenitese
                LD B,1          ; Alfunkcio kodja
                                ; 1 = videolap kijelzese
                LD A,1          ; A-ba a csatornaszam
                LD C,1          ; Az elso kijelzensdo sor az 1-es
                LD D,20         ; 20 sort kell megjeleniteni
                LD E,1          ; Az elso sorban kezdodik a megjelenites
                EXOS 11

                ; ESCAPE szekvenciak kiirasa
                LD A,1          ; A-ba a csatornaszam
                LD BC,HOSSZ     ; BC-be a blokk hossza
                                ; (A HOSSZ cimen levo ertek)
                LD DE,ESC1      ; DE-be a blokk kezdocime
                EXOS 8          ; Blokk kiirasa

                ;Varakozas billentyu leutesere
                LD DE,BILL      ; DE a nev elotti hosszbyte-ra mutat
                LD A,3          ; A-ba a csatornaszam
                EXOS 1          ; Csatorna megnyitasa
                LD A,3          ; A-ba a csatornaszam
                EXOS 5          ; Karakterolvasas
                JP VISSZATERES  ; Ugrik a befejezesre

VISSZATERES     LD A,1          ; A-ba a csatornaszam
                EXOS 3          ; Csatorna lezarasa
                LD DE,BASIC     ; Visszater a BASIC-be
                EXOS 26         ; Bovitesek vizsgalata

VID             DB 6,"VIDEO:"   ; A megnyitashoz szukseges nev
BILL            DB 9,"KEYBOARD:" ; A megnyitashoz szukseges nev
BASIC           DB 5,"BASIC"    ; BASIC-cimke
ESC1            DB 27,"C",203,0,0,203,0,0,0,0
                                ; A paletta szineinek beallitasa
                DB 27,"A"       ; Rajzolosugar pozicionalasa
                DW 600,300      ; A kor kozeppontja
                DB 27,"E"       ; Kor rajzolasa
                DW 120,120      ; A kor mereteinek megadasa
HOSSZ           EQU $-ESC1      ; Hosszbyte meghatarozasa
                END             ; Program vege